#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>
#include <EEPROM.h>
#include <avr/wdt.h>

//Uncomment if you are in USA
//#define Fahrenheit

#define POLL_COUNT    (4)
#define POLL_BASE     (60)

const int RELAY = 0;
const int MODE = 9, UP = 12, DOWN = 11, SELECT = 10;

//CRC-8 (x^8 + x^5 + x^4 + 1) lookup table
static const byte CRC_8_TABLE[256] = 
{
    0x00, 0x31, 0x62, 0x53, 0xC4, 0xF5, 0xA6, 0x97, 0xB9, 0x88, 0xDB, 0xEA, 0x7D, 0x4C, 0x1F, 0x2E,
    0x43, 0x72, 0x21, 0x10, 0x87, 0xB6, 0xE5, 0xD4, 0xFA, 0xCB, 0x98, 0xA9, 0x3E, 0x0F, 0x5C, 0x6D,
    0x86, 0xB7, 0xE4, 0xD5, 0x42, 0x73, 0x20, 0x11, 0x3F, 0x0E, 0x5D, 0x6C, 0xFB, 0xCA, 0x99, 0xA8,
    0xC5, 0xF4, 0xA7, 0x96, 0x01, 0x30, 0x63, 0x52, 0x7C, 0x4D, 0x1E, 0x2F, 0xB8, 0x89, 0xDA, 0xEB,
    0x3D, 0x0C, 0x5F, 0x6E, 0xF9, 0xC8, 0x9B, 0xAA, 0x84, 0xB5, 0xE6, 0xD7, 0x40, 0x71, 0x22, 0x13,
    0x7E, 0x4F, 0x1C, 0x2D, 0xBA, 0x8B, 0xD8, 0xE9, 0xC7, 0xF6, 0xA5, 0x94, 0x03, 0x32, 0x61, 0x50,
    0xBB, 0x8A, 0xD9, 0xE8, 0x7F, 0x4E, 0x1D, 0x2C, 0x02, 0x33, 0x60, 0x51, 0xC6, 0xF7, 0xA4, 0x95,
    0xF8, 0xC9, 0x9A, 0xAB, 0x3C, 0x0D, 0x5E, 0x6F, 0x41, 0x70, 0x23, 0x12, 0x85, 0xB4, 0xE7, 0xD6,
    0x7A, 0x4B, 0x18, 0x29, 0xBE, 0x8F, 0xDC, 0xED, 0xC3, 0xF2, 0xA1, 0x90, 0x07, 0x36, 0x65, 0x54,
    0x39, 0x08, 0x5B, 0x6A, 0xFD, 0xCC, 0x9F, 0xAE, 0x80, 0xB1, 0xE2, 0xD3, 0x44, 0x75, 0x26, 0x17,
    0xFC, 0xCD, 0x9E, 0xAF, 0x38, 0x09, 0x5A, 0x6B, 0x45, 0x74, 0x27, 0x16, 0x81, 0xB0, 0xE3, 0xD2,
    0xBF, 0x8E, 0xDD, 0xEC, 0x7B, 0x4A, 0x19, 0x28, 0x06, 0x37, 0x64, 0x55, 0xC2, 0xF3, 0xA0, 0x91,
    0x47, 0x76, 0x25, 0x14, 0x83, 0xB2, 0xE1, 0xD0, 0xFE, 0xCF, 0x9C, 0xAD, 0x3A, 0x0B, 0x58, 0x69,
    0x04, 0x35, 0x66, 0x57, 0xC0, 0xF1, 0xA2, 0x93, 0xBD, 0x8C, 0xDF, 0xEE, 0x79, 0x48, 0x1B, 0x2A,
    0xC1, 0xF0, 0xA3, 0x92, 0x05, 0x34, 0x67, 0x56, 0x78, 0x49, 0x1A, 0x2B, 0xBC, 0x8D, 0xDE, 0xEF,
    0x82, 0xB3, 0xE0, 0xD1, 0x46, 0x77, 0x24, 0x15, 0x3B, 0x0A, 0x59, 0x68, 0xFF, 0xCE, 0x9D, 0xAC
};

Adafruit_SSD1306 display(128, 32, &Wire, 4);

float result;
byte low, high;
unsigned int rawResult;
byte bufferRaw[3], CRC;
int loopCounter, mode, selectRow, index, relayOutput;
int modeCount, upCount, downCount, selectCount;
bool modePressed, upPressed, downPressed, selectPressed;

void setup() {
  pinMode(RELAY, OUTPUT);
  pinMode(MODE, INPUT_PULLUP);
  pinMode(UP, INPUT_PULLUP);
  pinMode(DOWN, INPUT_PULLUP);
  pinMode(SELECT, INPUT_PULLUP);
  
  low = EEPROM.read(0);
  high = EEPROM.read(1);
  if(255 == low) low = 40;
  if(255 == high) high = 50;
  relayOutput = 0; //Default is off
  loopCounter = 0;
  mode = 0, selectRow = 0;
  modeCount = POLL_BASE, upCount = POLL_BASE, downCount = POLL_BASE, selectCount = POLL_BASE;
  
  Wire.begin();
  Wire.setClock(10000);

  display.begin(SSD1306_SWITCHCAPVCC, 0x3C);
  display.clearDisplay();
  display.setTextSize(2);
  display.setTextColor(WHITE);
  display.cp437(true);

  wdt_enable(WDTO_4S);
}

void loop() {
  pollButtons();
  loopCounter++;
  delay(10);
  
  processMode();
  processSelect();
  processUp();
  processDown();
  
  if(40 != loopCounter) return;  
  loopCounter = 0; 
  wdt_reset(); 

  display.clearDisplay();  
  if(0 == mode) processMainScreen();
  if(1 == mode) processSetupScreen();
  display.display();
}

void processMode() {
  if(!modePressed) return;
  
    modePressed = false;
    if(0 == mode) {
      mode = 1;
      return;
    }
    if(1 == mode) {
      mode = 0;
      if(low != EEPROM.read(0)) EEPROM.write(0, low);
      if(high != EEPROM.read(1)) EEPROM.write(1, high);
      return;
    }
}

void pollButtons() {
  //----Mode button-----------------------------------  
  if(LOW == digitalRead(MODE)) modeCount++;
  else modeCount = POLL_BASE;
  
  if((POLL_BASE + POLL_COUNT) <= modeCount)
  {
      modePressed = true; 
      modeCount = 0;
  }

  //----Up button-------------------------------------
  if(LOW == digitalRead(UP)) upCount++;
  else upCount = POLL_BASE;
  
  if((POLL_BASE + POLL_COUNT) <= upCount)
  {
      upPressed = true; 
      upCount = 0;
  }
  
  //----Down button-----------------------------------
  if(LOW == digitalRead(DOWN)) downCount++;
  else downCount = POLL_BASE;
  
  if((POLL_BASE + POLL_COUNT) <= downCount)
  {
      downPressed = true; 
      downCount = 0;
  }
  
  //----Select button---------------------------------
  if(LOW == digitalRead(SELECT)) selectCount++;
  else selectCount = POLL_BASE;
  
  if((POLL_BASE + POLL_COUNT) <= selectCount)
  {
      selectPressed = true; 
      selectCount = 0;
  }
}

void processUp() {
  if(!upPressed) return;
  upPressed = false;
  if(0 == mode) return;

  if(0 == selectRow) {
    high++;
    if(101 <= high) high = 0;
  }
  else {
    low++;
    if(101 <= low) low = 0;
  }
}

void processDown() {
  if(!downPressed) return;
  downPressed = false;
  if(0 == mode) return; 

  if(0 == selectRow) {
    high--;
    if(255 == high) high = 100;
    
  }
  else {    
    low--;
    if(255 == low) low = 100;
  }
}

void processSelect() {
  if(!selectPressed) return;
  
  selectPressed = false;
  if(0 == mode) selectRow = 0;
  if(1 == mode) {
    if(0 == selectRow) {
      selectRow = 1;
      return;
    }
    if(1 == selectRow) {
      selectRow = 0;
      return;
    }
  }
}

void processMainScreen() {  
  getRH();

  if(low > result) relayOutput = 1;
  if(high < result) relayOutput = 0;
  digitalWrite(RELAY, relayOutput); 
    
  getTemperature();
}

void processSetupScreen() {
  display.setCursor(100, selectRow * 16);
  display.print((char)27);
  
  display.setCursor(0, 0);
  display.print(F("H: "));
  display.print(high);

  display.setCursor(0, 16);
  display.print(F("L: "));
  display.print(low);
}

void getRH() {
  //Triggering RH measurement
  Wire.beginTransmission(0x40);
  Wire.write(0xE5);
  Wire.endTransmission();

  //Requesting result (3 bytes: 2 bytes for value and 1 for checksum)
  Wire.requestFrom(0x40, 3);
  index = 2;
  while(Wire.available()) {
    bufferRaw[index] = Wire.read();
    if(0 == index) {
      //Trying to display result if it's correct
      showRH();
      break;
    }
    index--;
  }
}

void getTemperature() {
  //Triggering temperature measurement
  Wire.beginTransmission(0x40);
  Wire.write(0xE3);
  Wire.endTransmission();

  //Requesting result (3 bytes: 2 bytes for value and 1 for checksum)
  Wire.requestFrom(0x40, 3);
  index = 2;
  while(Wire.available()) {
    bufferRaw[index] = Wire.read();
    if(0 == index) {
      //Trying to display result if it's correct
      showTemperature();
      break;
    }
    index--;
  }
}

void showRH() {
  display.setCursor(10, 0);
  if(checkChecksum(bufferRaw[2], bufferRaw[1], bufferRaw[0])) {
    rawResult = (bufferRaw[2] << 8) | (bufferRaw[1] & B11111100);
    result = rawResult * 125.0 / 65536.0 - 6.0;
    display.print(F("RH:"));
    display.print(result, 1);
    display.print(F("%"));
  }
  else
    display.print(F("RH: error"));
}

void showTemperature() {  
  display.setCursor(10, 16);
  if(checkChecksum(bufferRaw[2], bufferRaw[1], bufferRaw[0])) {
    rawResult = (bufferRaw[2] << 8) | (bufferRaw[1] & B11111100);
    result = rawResult * 175.72 / 65536.0 - 46.85;
    
    #ifdef Fahrenheit
      result = result * 1.8 + 32.0;
    #endif
    
    display.print(F(" T:"));
    display.print(result, 1);

    #ifdef Fahrenheit
      display.print(F("F"));
    #else
      display.print(F("C"));
    #endif
  }
  else
    display.print(F("Temp: error"));
}

bool checkChecksum(byte MSB, byte LSB, byte checksum) {
  CRC = 0;
  CRC = CRC_8_TABLE[CRC ^ MSB];
  CRC = CRC_8_TABLE[CRC ^ LSB];
  if(CRC == checksum) return true; 
  return false;
}